REM Compilazione degli script macchina Egaltech                         2024.02.22
REM Per togliere info di debug aggiungere flag -s prima del nome del file di input

REM Compilazione 32 bit e copia file da non compilare

@echo off

REM chiedo all'utente la versione da assegnare alla macchina da compilare
set /p "machineVersion=Inserisci versione: "

REM variabili per costruire i percorsi delle cartelle
set "machineName=Essetre-PFrl"
set "deployFolder=C:\MachinesDeploy"
set "machinePath=%deployFolder%\%machineName%\"
set "fullPathSource=%deployFolder%\%machineName%\%machineVersion%\%machineName%"
set "fullPathZip=%deployFolder%\%machineName%\%machineVersion%"

REM elimino eventuale cartella esistente
rmdir /s /Q %fullPathZip%

REM copio i sorgenti nel percorso di destinazione
ROBOCOPY . %fullPathSource%\ /E /XF "Compile.bat" /XF ".gitignore" /XD ".git" /XF "UpdateLog.txt"
REM copio i sorgenti nel percorso temporaneo per i compilati
ROBOCOPY . %fullPathSource%\bin\%machineName%\ /E /XF "Compile.bat" /XF ".gitignore" /XD ".git" /XF "UpdateLog.txt"

REM copio i file compilati nel percorso temporaneo per i compilati
\EgtProg\Dll32\luac54 -o %fullPathSource%\bin\%machineName%\Common_ONE-PF.mlpe	 	           		  -s Common_ONE-PF.mlpe	 
\EgtProg\Dll32\luac54 -o %fullPathSource%\bin\%machineName%\Common_ONE-PF.mlse                       -s Common_ONE-PF.mlse    
\EgtProg\Dll32\luac54 -o %fullPathSource%\bin\%machineName%\Common_ONE-PF.NUM.mlpe                   -s Common_ONE-PF.NUM.mlpe  

REM comprimo i file compilati in uno zip pronto per essere distribuito
tar.exe acvf %fullPathZip%\%machineName%.zip -C %fullPathSource%\bin\ %machineName%\*.*

REM elimino il percorso temporaneo
rmdir /s /Q %fullPathSource%\bin\