EgtCAM5/SpecialPanel/SpecialPanelVM.vb

Imports System.IO
Imports EgtUILib

Public Class SpecialPanelVM

   Private m_ButtonList As New List(Of ButtonItem)
   Public ReadOnly Property ButtonList As List(Of ButtonItem)
      Get
         Return m_ButtonList
      End Get
   End Property

   Sub New()
      ' Creo riferimento a questa classe in Map
      Map.SetRefSpecialPanelVM(Me)
      ' se attivo, inizializzo i bottoni leggendoli da file ini
      If IniFile.IsActiveSpecialPanel Then
         Dim BtnIndex As Integer = 1
         Dim CurrBtn As ButtonItem = Nothing
         While GetPrivateProfileButton(S_SPECIAL, K_BUTTON & BtnIndex, "", CurrBtn)
            m_ButtonList.Add(CurrBtn)
            BtnIndex += 1
         End While
      End If
   End Sub

#Region "METHODS"

   Public Function SetSpecialPanelButtonsVisibility(IsMachMode As Boolean) As Boolean
      Dim bSpecialPanel_Visible As Boolean = False
      For Each BtnItem In m_ButtonList
         ' verifico il valore di nDrawMachOrBoth del bottone e IsMachMode per rendere visibile o meno il bottone in ButtonList
         Select Case BtnItem.nDrawMachOrBoth
            Case 0 ' bottone visibile sia in Draw che in Machining
               BtnItem.m_Btn_Visibility = Visibility.Visible
            Case 1 ' bottone visibile solo in Draw
               BtnItem.m_Btn_Visibility = If(Not IsMachMode, Visibility.Visible, Visibility.Collapsed)
            Case 2 ' bottone visibile solo in Machining
               BtnItem.m_Btn_Visibility = If(IsMachMode, Visibility.Visible, Visibility.Collapsed)
         End Select
         ' se anche uno solo è visibile anche lo SpecialPanel dovrà esserlo
         If BtnItem.Btn_Visibility = Visibility.Visible Then bSpecialPanel_Visible = True
         BtnItem.OnPropertyChanged(NameOf(BtnItem.Btn_Visibility))
      Next
      Return bSpecialPanel_Visible
   End Function

   Friend Sub SpecialPanelIsEnabled(SpecialPanelBtn_IsEnabled As Boolean)
      For Each BtnItem In m_ButtonList
         BtnItem.m_Btn_IsEnabled = SpecialPanelBtn_IsEnabled
         BtnItem.OnPropertyChanged(NameOf(BtnItem.Btn_IsEnabled))
      Next
   End Sub

#End Region    ' Methods

End Class

Public Class ButtonItem
   Inherits ViewModelBase

   Private m_sImagePath As String
   Public ReadOnly Property ImagePath As String
      Get
         Return m_sImagePath
      End Get
   End Property
   Private m_sLuaCmdPath As String
   Private m_sToolTip As String
   Public ReadOnly Property ToolTip As String
      Get
         Return m_sToolTip
      End Get
   End Property
   Private m_nDrawMachOrBoth As Integer
   Public ReadOnly Property nDrawMachOrBoth As Integer
      Get
         Return m_nDrawMachOrBoth
      End Get
   End Property
   Friend m_Btn_Visibility As Visibility
   Public ReadOnly Property Btn_Visibility As Visibility
      Get
         Return m_Btn_Visibility
      End Get
   End Property

   Friend m_Btn_IsEnabled As Boolean = True
   Public ReadOnly Property Btn_IsEnabled As Boolean
      Get
         Return m_Btn_IsEnabled
      End Get
   End Property

   ' Definizione comandi
   Private m_cmdLuaExec As ICommand

   Sub New(sLuaCmdPath As String, sImagePath As String, sToolTip As String, sDrawMachOrBoth As String)
      If File.Exists(sImagePath) Then
         m_sImagePath = sImagePath
      Else
         m_sImagePath = IniFile.m_sResourcesRoot & "\" & sImagePath
      End If
      m_sLuaCmdPath = sLuaCmdPath
      m_sToolTip = sToolTip
      If Not Integer.TryParse(sDrawMachOrBoth, m_nDrawMachOrBoth) Then m_nDrawMachOrBoth = 0
   End Sub

#Region "COMMANDS"

#Region "LuaExecCommand"

   ''' <summary>
   ''' Returns a command that do New.
   ''' </summary>
   Public ReadOnly Property LuaExecCommand As ICommand
      Get
         If m_cmdLuaExec Is Nothing Then
            m_cmdLuaExec = New Command(AddressOf LuaExec)
         End If
         Return m_cmdLuaExec
      End Get
   End Property

   ''' <summary>
   ''' Execute the New.  This method is invoked by the NewCommand.
   ''' </summary>
   Public Sub LuaExec(ByVal param As Object)
      If String.IsNullOrWhiteSpace(m_sLuaCmdPath) Then Return
      ' se trovo costante di apertura file lavorazioni travi
      If m_sLuaCmdPath = BeamPanelVM.BEAM_MACHININGS Then
         Beam.BeamMachDb()
         Return
         ' se altrimenti per pareti
      ElseIf m_sLuaCmdPath = WallPanelVM.WALL_MACHININGS Then
         Wall.WallMachDb()
         Return
      End If
      If Not File.Exists(m_sLuaCmdPath) Then Return
      If Not Path.GetExtension(m_sLuaCmdPath).ToLower = ".lua" Then Return
      ' eseguo file Lua
      Map.refProjectVM.PreExecScript(False)
      Map.refProjectVM.ExecScript(m_sLuaCmdPath)
   End Sub

#End Region ' LuaExecCommand

#End Region    ' Commands

End Class